ERLANDSEN DATA CONSULTING Excel & VBA Tips   Information in English / Informasjon på engelsk

Disse websidene oppdateres ikke lengre og er kun tilgjengelig for historikken sin skyld.

Klikk her for å gå til den oppdaterte informasjonen.

Funksjoner som teller

I Excel kan du telle innholdet i celler som tilfredsstiller forskjellige kriterier på flere måter. Følgende funksjoner kan benyttes :

  • ANTALL
    Teller antall celler i et angitt område som inneholder tallverdier.
  • ANTALLA
    Teller antall celler i et angitt område som er utfylt med tall, tekst eller formler.
  • TELLBLANKE
    Teller antall celler som ikke er utfylt innenfor et angitt område.
  • ANTALL.HVIS
    Teller antall celler i et angitt område som tilfredsstiller et angitt kriterie
  • En matriseformel er nyttig hvis de ovennevnte teknikkene ikke kan benyttes.
  • DANTALL
    Dataene må lagres som en tabell med overskriftskolonner, og et separat utvalgsområde for spørrekriteriene må benyttes.
    Mer informasjon om databasefunksjoner.

Nedenfor finnes noen eksempler som viser de forskjellige måtene å telle på. Man kan benytte et egendefinert navn i stedet for å benytte cellereferansen i formlene.

Beskrivelse Formel
Returnerer antall tall i det angitte området =ANTALL(E4:E23)
Returnerer antall utfylte celler i det angitte området =ANTALLA(E4:E23)
Returnerer antall blanke celler i det angitte området =TELLBLANKE(E2:E23)
Returnerer antall positive tall i det angitte området =ANTALL.HVIS(E4:E23;">0")
Returnerer antall negative tall i det angitte området =ANTALL.HVIS(E4:E23;"<0")
Returnerer antall celler som inneholder ja =ANTALL.HVIS(F4:F23;"ja")
Returnerer antall celler som inneholder tekst som begynner på k =ANTALL.HVIS(F4:F23;"k*")
Returnerer antall celler som inneholder tekst med bokstaven a =ANTALL.HVIS(F4:F23;"*a*")
Returnerer antall celler som inneholder ja eller nei =ANTALL.HVIS(F4:F23;"ja")+ANTALL.HVIS(F4:F23;"nei")
Returnerer antall celler som inneholder ja eller nei (matriseformel) {=SUMMER((F4:F23="ja")+(F4:F23="nei"))}
Returnerer antall celler som inneholder 3 tegn =ANTALL.HVIS(F4:F23;"???")
Returnerer antall celler med verdi mellom 30 og 80 =ANTALL.HVIS(E4:E23;">=30")-ANTALL.HVIS(E4:E23;">80")
Returnerer antall unike tall i det angitte området =SUMMER(HVIS(FREKVENS(E4:E23;E4:E23)>0;1;0))
Teller antall oddetall i det angitte området (matriseformel) {=SUMMER(REST(G4:G23;2))}
Teller antall partall i det angitte området (matriseformel) {=SUMMER(HVIS(REST(G4:G23;2)=0;1;0))}
Teller antall celler ut i fra to OG-kriterier (matriseformel) {=SUMMER(HVIS((F4:F23="ja")*(G4:G23>10);1;0))}
Teller antall celler ut i fra to OG-kriterier (matriseformel) {=SUMMER((F5:F24="ja")*(G5:G24>10))}
Teller antall celler ut i fra to ELLER-kriterier (matriseformel) {=SUMMER((F4:F23="ja")+(F4:F23="nei"))}

 

 

Dokumentet er sist oppdatert 1999-07-30 12:42:14      Utskriftsvennlig versjon

 

Erlandsen Data Consulting     http://www.erlandsendata.no/   
Excel & VBA Tips   Copyright ©1999-2017    Ole P. Erlandsen   All rights reserved
E-post kontaktadresse